# `ss`, `ssr`

_String search and replace_

## `ss`

_String search_
```syntax
x ss y     ss[x;y]
```

Where

- `x` is a string
- `y` is a [pattern](regex.md) as a char atom or string (`ss` doesn't support `*` as a wildcard)

returns a long vector of the positions within `x` of substrings that match pattern `y`.
```q
q)"We the people of the United States" ss "the"
3 17

q)s:"toronto ontario"
q)s ss "ont"
3 8
q)s ss "[ir]o"
2 13
q)s ss "t?r"
0 10
```

Matches do not overlap: after a match, the search resumes at the end of the matched substring.
```q
q)"aaaa" ss "aa"
0 2
```

## `ssr`

_String search and replace_
```syntax
ssr[x;y;z]
```

Where

- `x` is a string
- `y` is a [pattern](regex.md) as a char atom or string (`ssr` doesn't support `*` as a wildcard)
- `z` is a string or a function

returns `x` with each substring matching `y` replaced by:

- `z` if `z` is a string
- `z[Y]` if `z` is a function, where `Y` is the matched substring
```q
q)s:"toronto ontario"
q)ssr[s;"ont";"x"]      / replace "ont" by "x"
"torxo xario"
q)ssr[s;"t?r";upper]    / replace matches by their uppercase
"TORonto onTARio"
```

## Perl-compatible regular expressions

`ss` and `ssr` match each pattern character to exactly one character of `x`. For full regular expressions, use the [PCRE2 module](../modules/pcre2/overview.md). `pcre2.match` returns each matched substring with its start and end positions, and `pcre2.replace` supports references to captured groups in the replacement.
```q
q)"abc 123 de 45" ss "[0-9]"
4 5 6 11 12
q)pcre2:use`kx.fusion:pcre2
q)pcre2.match["[0-9]+";"abc 123 de 45";::]
x0| "123" 4  7  "45"  11 13
q)pcre2.replace["([a-z]+)@([a-z]+)";"me@host";"$2 at $1";::]
"host at me"
```

----

[`like`](like.md)


[Regular expressions in q](regex.md),
[PCRE2 module](../modules/pcre2/overview.md)


[Strings](by-topic.md#strings)
